define_tag(
	'wrap',
	-namespace='string_',
	-req='text', -copy,
	-opt='length', -copy, -type='integer',
	-opt='linebreak', -type='string',
	-opt='trim', -type='boolean',
	-priority='replace',
	-description='Wraps the given string to the specified length.'
);
	local(
		'in' = string(#text),
		'out' = string
	);
	
	!local_defined('length') ? local('length' = 80);
	#length -= 1;
	
	!local_defined('linebreak') ? local('linebreak' = '\n');
	
	!local_defined('trim') ? local('trim' = true);
	
	#in->trim;
	#in->replace('\r\n','\n')&replace('\r','\n');
	
	iterate(#in->split('\n'), local('i'));
		local('line' = #i);
	
		#trim ? #line->trim;
	
		if(#line->size < #length);
			#out += #line + #linebreak;
		else;
			local(
				'lineIn' = #line,
				'lineOut' = string
			);
			
			while(#lineIn->size > #length);
				local('offset' = #length);
				
				while(#lineIn->size > #offset && #offset > 0 && !#lineIn->isspace(#offset));
					#offset -= 1;
				/while;
				
				#offset == 0 ? #offset = #length;
			
				local('chunk') = #lineIn->substring(1, #offset);
			
				#lineOut += #chunk + #linebreak;
				#lineIn->removeleading(#chunk);
			/while;
			
			#lineIn->size ? #lineOut += #lineIn + #linebreak;
			
			#out += #lineOut;
		/if;
	/iterate;
	
	return(#out);
/define_tag;