Count the number of fields in a CSV file

The code below counts the number of fields in a CSV file. Since a CSV file could have a field broken across multiple lines, the code is setup to read a line at a time and check to see if it has a complete CSV row. If not, it continues reading lines until it does.

To set this up, the file object is created with this call: [file(#path, io_file_o_rdonly, file_modeLine)]. This opens the specified file specifying the open mode as read only and the get mode as returning a line at a time instead of a character at a time.

Code

define csv_fieldCount(path::string)::integer => {
    // Open a file to read lines not characters
    local(data_file) = file(#path, io_file_o_rdonly, file_modeLine)
    handle => {#data_file->close}

    // Parsing the CSV file
    // Keep reading lines until we run out of lines or until we get a complete CSV line to count # of fields
    local(csv_line)     = ''
    local(parsed_csv)   = array
    local(need_joining) = ''
    while(true) => {
        #csv_line = string(#data_file->get)
        fail_if(not #csv_line, -1, "NOT A CSV FILE: " + #path)

        iterate(#csv_line->split(',')) => {
            if(loop_value->first != '"' && #need_joining == '') => {
                #parsed_csv->insert(loop_value)
                loop_continue
            }
            loop_value->remove(1,1)
            // Count the ending number of " that don't include \" 
            // (for cases such as \"""", the first " won't be included since it is preceded by a backslash)
            // If it ends in an even number, we don't have a properly closed off field yet
            local(count_quotes) = regexp(-input=loop_value, -find=`(?:[^\\])("+)$`)
            if(loop_value != '"' and (not #count_quotes->find or #count_quotes->matchString(1)->size % 2 == 0)) => {
                #need_joining += loop_value + ','
                loop_continue
            }
            #need_joining += loop_value->remove(loop_value->size)&
            #parsed_csv->insert(#need_joining)
            #need_joining = ''
        }

        if(#need_joining == '') => { loop_abort }
        #need_joining += "\n"
    }

    return #parsed_csv->size
}

// Assume the contents of /path/to/file.csv look like this:
// "One, field",2,,4,"Fifth field",6
csv_fieldCount('/path/to/file.csv')

Result

6